Makaleler

Aralık Tabanlı Koşullu Formüller

Aralık Tabanlı Koşullu Formüller

Makalemizde, bir aralığa ölçüt uygulayan ve sağlanan ölçütlere göre tek bir sonuç döndüren Aralık Tabanlı Koşullu Formüller yer almaktadır. Bu işlevler aralık tabanlı, koşullu işlem gerçekleştirir.

Aralık Tabanlı Koşullu Formüller listesi:

FORMÜL AMAÇ
EĞERORTALAMA Tek kriterli koşullu ortalama
ÇOKEĞERORTALAMA Bir veya daha fazla kritere sahip koşullu ortalama
EĞERSAY Tek kriterli koşullu sayma
ÇOKEĞERSAY Bir veya daha fazla kritere sahip koşullu sayma
ÇOKEĞERMİN Bir veya daha fazla kritere sahip koşullu minimum
ÇOKEĞERMAK Bir veya daha fazla kritere sahip koşullu maksimum
ETOPLA Tek kriterli koşullu toplama
ÇOKETOPLA Bir veya daha fazla kritere sahip koşullu toplama

Yukarıdaki formüllerin üzerine tıklayarak, her bir formülle ilgili detay bilgilere erişebilirsiniz.

Farklılıkları Nelerdir?

Bu formüller yaygın olarak kullanılsa da, fark etmemiş olabileceğiniz iki anahtar yolla farklı şekilde çalışırlar.

  • Mantıksal ifadeler iki bölüme ayrılmıştır.
  • Aralık gerekli, dizileri değiştiremezsiniz.

Aşağıda, bu farklılıkları ayrıntılı olarak anlatacağız.

Bu formüllerin nasıl çalıştığını anladıktan sonra, istediğiniz şeyi yapmalarını daha kolay hale getirebilirsiniz. Ayrıca, alternatifleri ne zaman keşfetmeniz gerektiği konusunda daha iyi bir bilinciniz olacaktır.

Mantıksal ifadeler

Bu formüllerde diğerlerine göre önemli bir fark, mantıksal ifadeleri iki bölüme ayırarak ölçütleri özel bir şekilde uygulamalarıdır: aralık ve ölçütler.

Bu özellikler, kullanıcılara kolaylık ve rahatlık sağlamaktadır.

Örneğin, A1 hücresinde 5’ten büyük olduğunda DOĞRU sonucunu yazmak istediğinizi varsayalım. EĞER formülüyle bu sözdizimi basittir:

=EĞER(A1>5;DOĞRU)


Formül çok basittir. Mantıksal bir ifade olan A1>5; değeri bir mantık içerir ve benzer tüm değerleri test etmek için sütunun altına doğru kopyalayabiliriz:

EĞER Örneği

Diyelim ki EĞERSAY formülüyle A1:A10 aralığındaki, 5’ten büyük değerleri saymak istiyorsunuz. Bunun için aşağıdaki formül işinizi görecektir:

=EĞERSAY(A1:A10;”>5″)


Dikkat ederseniz, bu formül içerisinde (“> 5”) şeklinde bir ifade var, peki bu ne demektir?

A1:A10> 5 mantıksal ifadesinin iki bölüme ayrılmasıdır. A1:A10 aralığı formülün aralık yapısıyla birebir uyumlu olduğu için ilk formüldeki gibi geçerlidir, bu nedenle tırnaksız kalır. Ancak >5, kısmi ve geçersiz bir ifadedir, yani sayısal değildir. Formülün yapısı gereği ölçüt kısmına sayısal ya da metin değerlerini ayrı ayrı girmeni gerekir. Eğer hem sayısal bir değer hem de özel karakter vs metin şeklinde olan bir değeri birlikte kullanmanız gerekirse, yine “” işareti arasında yazmalısınız, yani “>5” gibi.

ÇOKEĞERSAY Örneği

Her ne kadar kriterimizi “>5” şeklinde kullansakta, EĞERSAY formülü kendi algoritmasında formülü şu şekle dönüştürür:

A1:A10>5 // Dönüştürülen ifade


Ölçütlere başka bir hücre eklediğimizde işler garipleşebilir. Örneğin, A1 hücresindeki değer, B1 hücresindeki değerden büyük büyük mü kontrolünü yapmalım. EĞER formülü ile bu çok basittir:

=EĞER(A1>B1;DOĞRU) // basit


Ancak diyelim ki A1:A10 aralığında, B1 hücresindeki değerden büyük olan değerleri saymak istiyoruz. Aşağıdaki formülü yazmak yeterli olacaktır:

=EĞERSAY(A1:A10;”>”&B1) // Oppss, bu nedir böyle? :)
 

Aralık Tabanlı Koşullu Formüller

Evet yukarıda göreceğiniz üzere sayısal değerleri sayıyoruz. Kriter olarak kullanmak için şartımız büyük “>” olması ama büyük olacak değeri elle yazmak yerine, B1 hücresindeki değerden almasını istiyoruyz. İşte burada birleştirme yapmanız gerektiğini unutmayalım. Konuyu anlattığımız birleştirme isimli makalemizi incelemenizi öneririz.

Kriteri Değerden Almak

Sayısal değerler basitçe böyledir.. Peki Metin değerleri ne olacak?

Bir hücrenin “Elma” ya eşit olup olmadığını kontrol etmek istediğimizi varsayalım. Bunun mantığıda EĞER formülü ile basittir:

=EĞER(A1=”Elma”;DOĞRU)


Metin Kriterli EĞER

Peki Elma’ya eşit hücreleri saymak istersek?

Aşağıdaki formüllerin her ikisi de çalışır:

=ÇOKEĞERSAY(A1:A10;”=Elma”)
=ÇOKEĞERSAY(A1:A10;”Elma”)


Temel olarak, “eşittir” (=) operatörü ima edilir, bu yüzden gerekli değildir, kullanmasanız da olur.

ÇOKEĞERSAY Metin Sayma

Yani mantık daha basit ama ilginç. Benzer şekilde, şunlardan biriyle 5’e eşit değerleri sayabilirsiniz:

=ÇOKEĞERSAY(A1:A10;”=5″)
=ÇOKEĞERSAY(A1:A10;5)


Yukarıdaki gibi formüllerin, her ikisi de çalışacaktır.

Özetlemek gerekirse, Aralık Tabanlı Koşullu Formüller mantıksal ifadeleri iki bölüme ayırdığı için benzersiz bir sözdizimi gerektirir:

  1. Mantıksal işleçleri içeren ölçütler çift tırnak içine alınmalıdır (“”)
  2. (=) Operatörüne eşittir atlanabilir (veya atlanamaz)
  3. Başka bir hücreye dayalı ölçütler, birleştirme kullanmalıdır

Şimdi ikinci temel farka, yani aralıklara bakalım.

Aralık Gerekliliği

Aralık Tabanlı Koşullu Formüllerinde gerekli olan ikinci alan Aralıktır. Aralık Tabanlı Koşullu Formülleri bir aralık istediğinde, bu aralığı sağlamanız gerekir. Bu formüllerde Dizi sağlayamazsınız.

Excel makaleleri yazarken, düşünceleri kelimelere çevirmek ve anlamlı cümleler oluşturmak zordur. Üstte bu zorluğu yaşadığımı düşünüyor ve ne demek istediğimi bir örnekle açıklamak istiyorum.

Diyelim ki; alttaki resimde yer alan A1:A10 aralığındaki tarih değerlerinden, Haziran ay’ına denk gelen tarihleri görmek istiyorsunuz.

EĞER formülü ve AY formülünü iç içe aşağıdaki gibi kullanabilirsiniz:

=EĞER(AY(A1)=6;DOĞRU)


Mantık basit, ay numarasını AY formülünü kullanarak bulun ve sonucu 6 ile karşılaştırın. Formülü B1 hücresine yazar ve B10 hücresine kadar kopyalarsam, Haziran ayındaki tarihler için DOĞRU ve YANLIŞ sonuçlarını alırız. Diğer tüm tarihler için sonuç:

EĞER ve AY Kullanımı

Bu arada üstteki formülümüz, bir formülü diğerinin içine yerleştirmenin bir örneğidir.

Aralık Tabanlı Koşullu Formüller

Şimdi, A1:A10 aralığındaki tarihler içerisinde, Haziran ayına denk tarihleri nasıl sayabiliriz? AY formülünü, EĞER ile yaptığımız gibi kullanabileceğimizi düşünebilirsiniz:

=ÇOKEĞERSAY(AY(A1:A10);6) // Sonuç Doğru mu?


Tabi ki HAYIR! Bu oldukça makul görünse de işe yaramayacak. Eğer deneme fırsatınız olursa, Excel’in formülü girmenize bile izin vermediğini, bunun yerine, “Bu formülle ilgili bir sorun var” hatası verdiğini göreceksiniz. Aslında, “SORUN” EĞERSAY için ilk argüman olarak bir aralık sağlamanız gerektiğidir. Tam da konumuzun özü işte budur.

AY formülü, bir dizideki 10 sayının tümünü doğru bir şekilde verecek olsa da, bir dizi ona yeterli olmayacak, bir aralık belirtmeniz gerekecektir.

Peki Haziran ayında tarihleri saymak için hangi formülü nasıl kullanabiliriz? Hemen alt satıra bakınız:

=ÇOKEĞERSAY(A1:A10;”>=”&TARİH(2020;6;1);A1:A10;”<=”&TARİH(2020;6;30))


ÇOKEĞERSAY ve AY Örneği

Temel olarak TARİH formülünü Haziran ay’ının başlangıç ve bitiş tarihlerini formüle sabitlemek için iki ölçüt olarak kullanıyoruz. 1 Haziran veya daha büyük tarihler için ilk koşul, 30 Haziran veya daha düşük tarihler için ikinci koşul.

“1-Haziran-2020” tarihini başka bir hücreye (B1) yazarsak, Haziran ayının son gününü hesaplamak için SERİAY formülünü kullanarak işleri biraz daha kolay hale getirebiliriz:

=ÇOKEĞERSAY(A1:A10;”>=”&B1;A1:A10;”<=”&SERİAY(B1;0))


ÇOKEĞERSAY ve SERİAY ÖRneği

Ama hala birleştirme yapmaktan başka şansımız yok. Ayrıca şunu belirtmek yararlı olacaktır, yukarıdaki ÇOKEĞERSAY örneğinin her ikisi de sadece Haziran değil, Haziran 2020’deki tarihler için işlem yapıyor.

Özetle, ÇOKEĞERSAY bir aralık gerektirdiğinden, bu aralıktaki değerleri doğrudan değiştirme gücünü kaybederiz.

Alternatifler

Peki, sınırlamaları olmayan bir formülle Haziran ayındaki tarihleri nasıl sayabiliriz? Excel Dinamik Dizi Formülleri gelmeden önce, TOPLA.ÇARPIM en net çözüm olacaktı:

=TOPLA.ÇARPIM(–(AY(A1:A10)=6))


Bu bir dizi formülüdür, ancak Ctrl + Shift + Enter gerektirmez. Excel’in Dinamik Dizi yapısının geldiği Ofis 365 versiyonunda da, TOPLA formülünü aynı şekilde kullanabiliriz:

=TOPLA.ÇARPIM(–(AY(A1:A10)=6))


Üstteki formül Excel’in önceki sürümlerinde Ctrl + Shift + Enter gerektirir, ancak Dinamik Excel’de sadece Enter ile çalışır.

Her iki formül de, DOĞRU ve YANLIŞ değerlerini 1 ve 0 ile değiştirmek için çift tire kullanılır, böylece sayılabilirler.

FİLTRE formülü şu şekilde kullanabiliriz:

=BAĞ_DEĞ_SAY(FİLTRE(A1:A10;AY(A1:A10)=6))


Bu bir formül daha içerir, ancak FİLTRE içinde ay boyunca test etmek için kullanılan mantığın tamamen aynı olduğuna dikkat edin.

Aralık Tabanlı Koşullu Formüller kullanımı kolaydır. Bu formülleri öğrenmek ve uygulamak, Excel’in gelecekte çıkaracağı formülleri kullanmayı, öğrenmeyi çok daha kolay hale getirecektir.

Faydalı olması temennisiyle.


Kıymetli ziyaretçimiz,

Web sitemize gösterdiğiniz ilgi ve ziyaret için teşekkürler. Her akşam ilgi çeken içeriklerimize, bir sıra dahilinde örnek Excel Dosyaları eklemekteyiz. Öncelik vermemizi istediğiniz içerik olursa, ilgili içeriğe yorum yapmanız yeterli olacaktır.

Daha fazla Excel Dosyasına hızlıca ve kolay bir şekilde sahip olmak için, binlerce hazır Excel dosyasının yer aldığı ExcelDepo'ya üye olmanızı tavsiye ederiz. Bilgilerinize sunarız.

Daha Fazla Göster

İlgili Makaleler

Bir cevap yazın

E-posta hesabınız yayımlanmayacak. Gerekli alanlar * ile işaretlenmişlerdir

Başa dön tuşu

Reklam Engelleyici Algılandı

Sitemizde gezinti yapabilmek ve hazır Excel dosyalarımızı indirebilmek için reklam engelleyicinizi kapatmanız gerekmektedir.